s u m a n s s h a l l o w t h o u g h t s

유난히 음악 얘기가 많은 미투데이. 어제 코디안님의 미투 페이지 설명문을 보니 "아이튠즈에서 듣고 있는 노래 제목을 설명문에 표시했으면 좋겠다"는 얘기가 보였다. 아, 그거 참 좋은 생각. 하여 가능한 방법을 찾아봤다.

아이튠즈 플러그인으로 만드는 방법이 가장 확실하겠으나, 개발시간이 많이 걸릴 것 같아 아이튠즈 정보를 폴링하는 간단한 애플 스크립트를 찾아 급 니즈 충족.

애플리케이션 형태로 저장해서 실행해두면 자동으로 아이튠즈에서 듣고 있는 음악을 설명문에 표시해 준다.

이게 꼭 맥용 아이튠즈가 아니라, 다른 다양한 음악듣기용 툴과 연계되면서, 함께 듣기까지 연계되면 참 좋겠다는 생각을 했고, 한번 몇가지 시도를 해봐야 겠다.

맥을 사용하는 개발능력이 되시는 분들은 애플스크립트에서 me2api를 이용하는 방법을 통해서 다른 시도들도 해보시길. 실제 해보니까 시간도 얼마 안걸리고 사용하기도 편하고 막 그런듯.

듣고 있는 곡명 미투로 전송하는 코드보기..

-- -----------------------------------------------------------------
-- Now Playing for me2day
-- -----------------------------------------------------------------

-- me2day user id & user key
property me2userid : "sumanpark"
property me2userkey : "********"
--------------------------------------------
property apiurl : "http://me2day.net/api/set_description/" & me2userid & ".xml"
property basic_auth_password : ""
property nonce : ""

property currentdata : ""
property prevdata : ""
property current_track : ""
property curr_position : ""
property is_on : false

on run
	tell application "Finder"
		try
			if (get name of every process) contains "iTunes" then set is_on to true
		on error
			set is_on to false
		end try
	end tell
	
	if is_on is true then
		tell application "iTunes"
			if player state is playing then
				set currentdata to " -d description=\"" & my encode_html((artist of the current track as Unicode text) & " - " & (name of the current track as Unicode text)) & "\""
			end if
		end tell
	end if
	
	if (currentdata is not equal to prevdata) then
		tell application "iTunes"
			if player position is greater than 5 then
				set pass to my get_basic_auth_password()
				
				do shell script ("curl -u " & me2userid & ":" & pass & " " & apiurl & currentdata)
				--return "curl -u " & me2userid & ":" & pass & " " & apiurl & currentdata
				set prevdata to currentdata
			end if
		end tell
	end if
	return 5
end run

property chars : {{"&", "and"}, {" ", "%20"}}

on get_basic_auth_password()
	if (length of basic_auth_password is greater than 0) then
		return basic_auth_password
	end if
	
	set my_nonce to my get_nonce()
	try
		do shell script "/sbin/md5 -qs " & my_nonce & me2userkey
	on error errMsg number errNo
		error errMsg number errNo
		return "failed"
	end try
	set basic_auth_password to my_nonce & result
	
	return basic_auth_password
end get_basic_auth_password

on get_nonce()
	
	if (length of nonce is greater than 0) then
		return nonce
	end if
	
	set hx to ""
	set hexc to "123456789abcdef"
	repeat 8 times
		set d to random number 15
		if d = 0 then
			set hx to hx & "0" as text
		else
			set hx to hx & (item d of hexc) as text
		end if
	end repeat
	set nonce to hx
	
	return nonce
end get_nonce

on encode_html(this_text)
	repeat with replaceStrItems in chars
		set this_text to my replace_chars(this_text, item 1 of replaceStrItems, item 2 of replaceStrItems)
	end repeat
	set this_text to my replace_unix(this_text)
end encode_html

on replace_chars(a_string, old_item, new_item)
	set AppleScript's text item delimiters to the old_item
	set the item_list to every text item of a_string
	set AppleScript's text item delimiters to the new_item
	set a_string to the item_list as string
	set AppleScript's text item delimiters to ""
	return a_string
end replace_chars

on replace_unix(a_string)
	set old_item to "\""
	set new_item to "\\\""
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "("
	set new_item to "\\("
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to ")"
	set new_item to "\\)"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "<"
	set new_item to "\\<"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to ">"
	set new_item to "\\>"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "'"
	set new_item to "\\'"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "?"
	set new_item to "\\?"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to ";"
	set new_item to "\\;"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "&"
	set new_item to "\\&"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "$"
	set new_item to "\\$"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "~"
	set new_item to "\\~"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "*"
	set new_item to "\\*"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "`"
	set new_item to "\\`"
	set a_string to replace_chars(a_string, old_item, new_item)
	set old_item to "|"
	set new_item to "\\|"
	set a_string to replace_chars(a_string, old_item, new_item)
	return a_string
end replace_unix

애플 스크립트 코드 편집기에서 Save As... Application 형태로 저장한 다음에 해당 실행파일을 돌리세요.